[résolu] volet roulant

arkoiuga · 19/12/2008, 16h43

j aimerai savoir s il est possible de faire des volets roulants qui s ouvrent et se ferment de bas en haut et de haut en bas avec une un interrupteur pour commander tous les volets de la maison en meme temps (2 volets)

Seb_01 · 19/12/2008, 19h27

Techniquement c'est possible et (pas trop compliqué) as tu fais des recherches sur Xstreet?

Si tu ne trouves rien de rien ... on essayera de te créer un truc sympa

Iceman Arkin · 20/12/2008, 14h19

Je dois avoir ton bonheur dans mon inventaire ...

Seb_01 · 23/12/2008, 09h00

J'ai vu ta demande de HUD et un volet qui monte ... dans un autre post lol...

Bref j'ai réalisé les scripts HUD + Volet + Objets (HUD + Volets)

Si tu es intéressé pour voir IG contacte moi en MP.

Je compléterai ce post plus tard en donnant scripts + photos + explications

HUD est un lapsus en fait c'est un objet plaqué au mur

mais tu peux le mettre aussi sur ton écran ... c'est comme tu veux...

Seb_01 · 23/12/2008, 13h02

I Création du boitier mural

Créer un box standard et la configurer avec l'éditeur

Le script du boitier mural

Options choisies:

Les volets sont des objets libres

La distance max distance boitiers/volets 20m

Pas de limites pour le nombre de volets (presque..)

Plusieurs boitiers possibles commandant tous les volets ( en vue d'une possible séparation par pièce..)

Canaux de comm non accessible et aléatoires.

Le script

Code PHP:


// variables globales //
integer listen_handle_1; // handler du  Listen

integer Reset_Syn_Channel;  // channel reservé à l'information " script de volet  reseté"

string   Action; // action demandée ( Up/Down)

integer Channel_SYNC;
integer Channel_Used;

key     UUID_UP      = "68114f49-b25b-9073-d6c4-84cbd544a4de";  // pic avec fleche UP rouge
key     UUID_DOWN    = "c3c8b4de-df83-1873-bdb7-5e26992a1696";  // pic avec fleche DOWN rouge
key     UUID_STAND_BY = "920febfb-f1b1-0389-3934-9f22c1333612"; // 2 fleches vertes

// code executable //
default
{
    on_rez (integer start_param)
    {
        llResetScript();     // force le reset du script 
    }
    
    state_entry()
    {
        llSetColor ( <0.0,0.0,0.0> , ALL_SIDES); // all black
        llSetColor ( <1.0,1.0,1.0> , 4);         // side used is blank
        llSetTexture ( UUID_STAND_BY,4 ); // texture 2 fleches vertes 
        
        Channel_SYNC      = -1000;      // canal sortant HUD ==> volets  
        Reset_Syn_Channel = -1010;      // canal entrant Volets ==> HUD
            
        Channel_Used = (integer) llFrand(1000) * -12345;  // canal aléatoire 
        
        listen_handle_1 = llListen(Reset_Syn_Channel, "", "", "");        // listen started
        
        llOwnerSay   ("Synchro asked...");        
        llSay    (Channel_SYNC, (string) (Channel_Used));  // communique le canal devant être utilisé pour communiquer

    }
    
    touch_start(integer num_detected)
    {
        vector position = llDetectedTouchST(0); // detecte la position du click de souris....
        
        llSetTimerEvent (2); // la pic correspondant au click sera maintenue affichée 2 secondes
        
        if (position.y > 0.5) 
        {   
            llSetTexture ( UUID_UP,4 ); // on affiche la fleche UP rouge
            Action = "UP";
        }
        else
        {   
            llSetTexture ( UUID_DOWN,4); // on affiche la fleche DOWN rouge
            Action = "DOWN";
        }
        llSay(Channel_Used, Action); // communique l'action choisie aux volets
        // llOwnerSay((string )Channel_Used); // Debug control canaux
    }
    
    listen( integer channel, string name, key id, string message )
    {
        if (message == "ASK_SYNC");  //  un reset a été réalisé sur des scripts des  volets. Il redemande le channel de comm..
        {
            llOwnerSay   ("Synchro asked...");        
            llSay    (Channel_SYNC, (string) (Channel_Used));     // on  redonne le cannal de com...        
    }   }
    
    
    timer()
    {
        llSetTexture ( UUID_STAND_BY,4 );  //   retour à deux flèches vertes...
    }
     
}

// Fin Part I

arkoiuga · 23/12/2008, 18h22

merci pour ta reponse seb j ai reussi a faire le boitier je fais comment pour faire le volet maintenant?

Seb_01 · 23/12/2008, 20h49

Demain à ton réveil ce sera publié ici...

arkoiuga · 23/12/2008, 20h50

merci seb

Seb_01 · 24/12/2008, 07h10

II Créations Volets

Petit film photos pour être faciliter les explications:

Le script

Code PHP:


integer Channel_Syn_Channel;
integer Reset_Syn_Channel;

float   X;
float   Y;
float   Z;

string Shutter;

Motor (string action)
{
// Methode testée  et retenue prim fixe  gestion de la texture un petit flash à la fin 
// mais le resultat  est très satisfaisant.
//
// l'image est composée de 2 zones 1 pleine  1 transarente 
// l'astuce a été  d'affichée au départ la zone pleine  (volet fermé ) et de deplacer l'image vers la zone transparente
// ou vice et versa  zone transparente vers zone pleine
// en fin d'animation on affiche la partie pleine or transparente en jouant de l'offset...     
// on synchronise les timing sleep & animation ...

    if  ( action == "DOWN"  &  Shutter == "OPENED")  
    {
        llSetTextureAnim(ANIM_ON  | SMOOTH | LOOP | REVERSE, ALL_SIDES , 2, 2, 1, 1, -0.25);        
        llSleep(4);
        llSetTextureAnim(FALSE, ALL_SIDES, 0, 0, 0.0, 0.0, 1.0);  // stop l'animation
        
        llSetPrimitiveParams([  PRIM_TEXTURE, 
                                ALL_SIDES, 
                                "e5f7ea6d-ce87-edc9-ea39-7d658c73ff1c",  // image 2 zones
                                <.5,1.0,0.0>,   //   1/2 image
                                <0.25,0.0,0.0>, //   offset    
                                PI_BY_TWO ]);  
        Shutter = "CLOSED";
    }
    else if (action == "UP"  & Shutter == "CLOSED") 
    {
  
        llSetTextureAnim(ANIM_ON  | SMOOTH | LOOP | REVERSE, ALL_SIDES , 2, 2, 1, 2, 0.25);        
        llSleep(4);
        llSetTextureAnim(FALSE, ALL_SIDES, 0, 0, 0.0, 0.0, 1.0); // stop l'animation
        
        llSetPrimitiveParams([  PRIM_TEXTURE, ALL_SIDES, "e5f7ea6d-ce87-edc9-ea39-7d658c73ff1c",
                                <.5,1.0,0.0>, <0.75,0.0,0.0>,PI_BY_TWO]);  
        Shutter = "OPENED"; 
    }
    

}


default
{
    on_rez(integer param)
    {   
        llResetScript();// Force the reset on rez.
    }

    state_entry()
    {           
        // Size  prim // >>>>>>>>>>>>A PARAMETRER  
        X =  9.7627;      
        Y =  0.010;      
        Z =  6.595;    
        
        llSetScale ( < X,Y,Z > );
        
        
        
        llSetPrimitiveParams([PRIM_TEXTURE, ALL_SIDES, "e5f7ea6d-ce87-edc9-ea39-7d658c73ff1c",
                          <.5,1.0,0.0>, <0.75,0.0,0.0>,PI_BY_TWO]);  // volet ouvert
        
        Shutter = "OPENED"; // status volet....  
        
        
        Channel_Syn_Channel = -1000;   //  canal de reception du channel  de com qui va être utilisé
        Reset_Syn_Channel   = -1010;   //  canal sortant pour indiqué au HUD  que l'on désire connaitre le cannal à utilisé 
        
        llListen(Channel_Syn_Channel, "", "", ""); // on est pret à recevoir le cannal de comm à utilisé 
        
        llSay (Reset_Syn_Channel, "ASK_SYNC");   // on demande le canal....          

    }
    
    
    listen( integer channel, string name, key id, string message )
    {
        if (channel == Channel_Syn_Channel)  
        {
            llListen((integer) message, "", "", ""); // Le message du HUD contient le ou si plusieurs boitiers plusieurs cannaux
            llOwnerSay ("Synchro done with the HUD");// C'est gràce à cela que les volets pourront être  pilotés.... par plusieurs boitiers....        
        }
        else 
            Motor( message );  // Action!!

    }

}

La mise en place prend 3 minutes... (only 2 prims) montre en main...

J'ai pas rencontrer de problèmes si tu relevais un bug fais moi en part stp.

Les 2 scripts peuvent être modifiée facilement pour gérer les volets pièce par pièces.

De même que remplacer les volets par une gestion de vitres opaques <====> transparentes est un jeu d'enfant ...

Vidéo

arkoiuga · 24/12/2008, 11h22

merci seb
j ai tout réussis tout fonctionne. Juste une petite chose j essais de mettre ma texture sur le volet je n y arrive pas il repasse an noir a chaque fois

Seb_01 · 24/12/2008, 11h39

Citation :

Publié par arkoiuga

merci seb
j ai tout réussis tout fonctionne. Juste une petite chose j essais de mettre ma texture sur le volet je n y arrive pas il repasse an noir a chaque fois

Ok

edit une box

et implémente çà

Code PHP:


default
{
    state_entry()
    {
        llSetTexture("e5f7ea6d-ce87-edc9-ea39-7d658c73ff1c", 4);

    }
}

regarde bien comment a été créée la texture

une partie transparente une partie pleine

inspire toi de cela pour en réaliser une avec TA texture (sur un logiciel photo externe)

ensuite importe là

dans ton inventaire copy to UUID

et remplace mon UUID par la tienne ...

C'est tout

si tu t'en sors pas

tu me donneras ta texture je te ferai le mask ...

Ps bravo pour le sans faute...

arkoiuga · 24/12/2008, 11h50

encore merci seb pour tes reponses rapides
j ai un souci je c est pas ce que c est : copy to UUID et remplace mon UUID par la tienne
et comment fait t on une texture a moitié transparente ?

Seb_01 · 24/12/2008, 12h08

il y a beaucoup de façon de le faire... du plus simple au plus compliqué...

une des méthodes simple

c'est de récupérer un couche alpha nom de code pour la transparence ou de la créer.
1 tu en récupère une n'importe où y compris celle de SL...

2 tu créé un image vierge et tu utilises ton logiciel pour la rendre transparente
bcp de logiciel le font je te rassure en générale l transparence est représente par un damier(quand tu la réalisée).

Ensuite tu prends ta texture et tu la colle en la dimensionant à la moité de l'autre comme ma texture

Tu la sauvegarde en png ( qui gère la couche alpha ...pas de jpeg/bmp ).

Tu l'importes de ton pc sur sl

Tu cliques droit sur le nom dans ton inventaire et tu as une option

ensuite Copy or Ctrl +v dans le code du script

j'ai modifié le code pour rendre UUID plus facile à géer:

Code PHP:


integer Channel_Syn_Channel;
integer Reset_Syn_Channel;

string  Channel_User;

float   X;
float   Y;
float   Z;

key UUID_Shuter = "e5f7ea6d-ce87-edc9-ea39-7d658c73ff1c" ; /// UUID à replacer ICI

string Shutter;

Motor (string action)
{
// Methode testée  et retenue prim fixe  gestion de la texture un petit flash à la fin 
// mais le resultat  est très satisfaisant.
//
// l'image est composée de 2 zones 1 pleine  1 transarente 
// l'astuce a été  d'affichée au départ la zone pleine  (volet fermé ) et de deplacer l'image vers la zone transparente
// ou vice et versa  zone transparente vers zone pleine
// en fin d'animation on affiche la partie pleine or transparente en jouant de l'offset...     
// on synchronise les timing sleep & animation ...

    if  ( action == "DOWN"  &  Shutter == "OPENED")  
    {
        llSetTextureAnim(ANIM_ON  | SMOOTH | LOOP | REVERSE, ALL_SIDES , 2, 2, 1, 1, -0.25);        
        llSleep(4);
        llSetTextureAnim(FALSE, ALL_SIDES, 0, 0, 0.0, 0.0, 1.0);  // stop l'animation
        
        llSetPrimitiveParams([  PRIM_TEXTURE, 
                                ALL_SIDES, 
                                UUID_Shuter,  // image 2 zones
                                <.5,1.0,0.0>,   //   1/2 image
                                <0.25,0.0,0.0>, //   offset    
                                PI_BY_TWO ]);  
        Shutter = "CLOSED";
    }
    else if (action == "UP"  & Shutter == "CLOSED") 
    {
  
        llSetTextureAnim(ANIM_ON  | SMOOTH | LOOP | REVERSE, ALL_SIDES , 2, 2, 1, 2, 0.25);        
        llSleep(4);
        llSetTextureAnim(FALSE, ALL_SIDES, 0, 0, 0.0, 0.0, 1.0); // stop l'animation
        
        llSetPrimitiveParams([  PRIM_TEXTURE, ALL_SIDES, UUID_Shuter,
                                <.5,1.0,0.0>, <0.75,0.0,0.0>,PI_BY_TWO]);  
        Shutter = "OPENED"; 
    }
    

}


default
{
    on_rez(integer param)
    {   
        llResetScript();// Force the reset on rez.
    }

    state_entry()
    {           
        // Size  prim // >>>>>>>>>>>>A PARAMETRER  
        X =  8.700;      
        Y =  0.010;      
        Z =  7.068;    
        
        llSetScale ( < X,Y,Z > );
        
        
        
        llSetPrimitiveParams([PRIM_TEXTURE, ALL_SIDES, UUID_Shuter,
                          <.5,1.0,0.0>, <0.75,0.0,0.0>,PI_BY_TWO]);  // volet ouvert
        
        Shutter = "OPENED"; // status volet....  
        
        
        Channel_Syn_Channel = -1000;   //  canal de reception du channel  de com qui va être utilisé
        Reset_Syn_Channel   = -1010;   //  canal sortant pour indiqué au HUD  que l'on désire connaitre le cannal à utilisé 
        
        llListen(Channel_Syn_Channel, "", "", ""); // on est pret à recevoir le cannal de comm à utilisé 
        
        llSay (Reset_Syn_Channel, "ASK_SYNC");   // on demande le canal....          

    }
    
    
    listen( integer channel, string name, key id, string message )
    {
        if (channel == Channel_Syn_Channel)  
        {
            llListen((integer) message, "", "", ""); // Le message du HUD contient le ou LES CANAUX à utilisé
            llOwnerSay ("Synchro done with the HUD");// C'est gràce à cela que les volet pourront être  piloté par plusieurs HUD....        
        }
        else 
            Motor( message );  // Action!!

    }

}

voilà

la texture utilisée

arkoiuga · 31/12/2008, 17h33

me revoili me revoila seb avec mon volet
j ai bien reussi a faire la texture tout est ok mais encore un tit soucis avec la photo tu comprendra tout.

https://forums.jeuxonline.info/attachment.php?attachmentid=63917&stc=1&d=1230740715

le prims que je fais pour la fenetre est a la taille de la fenetre
et ensuite il est devient plus grand comme tu vois sur la photo mais que dans le sens de la hauteur.

Seb_01 · 31/12/2008, 17h41

Bravo!

1.stop ton script ( running off ) position basse (fermé donc)
2. ensuite regle le correctement en hauteur z (reajuste la position si besoin)
3. note la valeur Z donnée dans édit
4. reporte cette valeur dans le script
5. compile le + running on
6. cela devrait le faire

// Size prim // >>>>>>>>>>>>A PARAMETRER
X = 8.700;
Y = 0.010;
Z = 7.068; <====== Hauteur ton volet

Madball Shan · 01/01/2009, 18h38

Merci seb pour ce joli tuto

J'ai fait des volets moi aussi tout fonctionne bien sauf un petit détail, en fait j ai fait de plus petits volets que les tiens et mon souci viens de la taille de la texture car quand mes volets déroules ça tourne un peu trop, presque en boucle (niveau anim texture), peut-on régler la hauteur de cette texture et si oui, quelle ligne du script.
Merci

Seb_01 · 01/01/2009, 19h45

Je suis étonné car la texture n'a pas d'importance que cela soit un volet de 10m
ou 1 m le temps sera identique pour la fermeture et l'ouverture

je viens de tester
http://www.wegame.com/watch/Grand_et_petit_volet/
la seule chose à faire c'est de copier UUID de la texture dans le script et de mettre dans le script les valeur définitives que tu as obtenu quand tu as fini d'ajuster tes dimensions ( que tu récupères dans edit x y z).

Le mieux à ce stade est de recopier MON UUID et te tester avec tes fenêtres.

Si après tu as toujours des problèmes je viendrai te voir IG.

Madball Shan · 01/01/2009, 20h15

J'ai refait et tout fonctionne bien maintenant. Merci

arkoiuga · 01/01/2009, 21h22

merci seb tout est ok pour moi maintenant

Seb_01 · 01/01/2009, 21h31

tu me rassures car je ne voyais pas le problème

Je vais mettre ce produit sous Xstreet cela sera plus simple pour les intéressés..

Fait

http://uncensored.xstreetsl.com/modu...ItemID=1107520

Madball Shan · 01/01/2009, 23h07

En fait je pense que c'est un bug du au lag car sur une sim ca fonctionne très bien puis sur une autre ça me fait toujours le même bug

Seb_01 · 02/01/2009, 07h54

Là je comprends mieux...

il n'y pas grand chose à faire je pense si c'est intrinsèque à la fonction "llSetTextureAnim"....

J'ai modifié le script maintenant il y a une variable appelée "Timing" pour régler le temps de l'animation donc le temps de montée et descente du volet...
<4 plus rapide
>4 moins rapide

Essaye de modifier cela pour tenter de contourner le lag.

3.8 3.6 etc
4.2 4.4 etc

Je suis très curieux techniquement du résultat...

Script modifié.
MAJ Xstreet faite aussi.

Code PHP:


integer Channel_Syn_Channel;
integer Reset_Syn_Channel;

string  Channel_User;

float   X;
float   Y;
float   Z;

string Shutter;
float Timing = 4; //   Ici on règle le temp de la l'animation donc le delai de fermeture et d'ouverture.... à ajuster

Motor (string action)
{
// Methode testée  et retenue prim fixe  gestion de la texture un petit flash à la fin 
// mais le resultat  est très satisfaisant.
//
// l'image est composée de 2 zones 1 pleine  1 transarente 
// l'astuce a été  d'affichée au départ la zone pleine  (volet fermé ) et de deplacer l'image vers la zone transparente
// ou vice et versa  zone transparente vers zone pleine
// en fin d'animation on affiche la partie pleine or transparente en jouant de l'offset...     
// on synchronise les timing sleep & animation ...

    if  ( action == "DOWN"  &  Shutter == "OPENED")  
    {
        llSetTextureAnim(ANIM_ON  | SMOOTH | LOOP | REVERSE, ALL_SIDES , 2, 1, 1, 1, -1/Timing);        
        llSleep(Timing);
        llSetTextureAnim(FALSE, ALL_SIDES, 0, 0, 0.0, 0.0, 1.0);  // stop l'animation
        
        llSetPrimitiveParams([  PRIM_TEXTURE, 
                                ALL_SIDES, 
                                "e5f7ea6d-ce87-edc9-ea39-7d658c73ff1c",  // image 2 zones
                                <.5,1.0,0.0>,   //   1/2 image
                                <0.25,0.0,0.0>, //   offset    
                                PI_BY_TWO ]);  
        Shutter = "CLOSED";
    }
    else if (action == "UP"  & Shutter == "CLOSED") 
    {
  
        llSetTextureAnim(ANIM_ON  | SMOOTH | LOOP | REVERSE, ALL_SIDES , 2, 1, 1, 2, 1/Timing);        
        llSleep(Timing);
        llSetTextureAnim(FALSE, ALL_SIDES, 0, 0, 0.0, 0.0, 1.0); // stop l'animation
        
        llSetPrimitiveParams([  PRIM_TEXTURE, ALL_SIDES, "e5f7ea6d-ce87-edc9-ea39-7d658c73ff1c",
                                <.5,1.0,0.0>, <0.75,0.0,0.0>,PI_BY_TWO]);  
        Shutter = "OPENED"; 
    }
    

}


default
{
    on_rez(integer param)
    {   
        llResetScript();// Force the reset on rez.
    }

    state_entry()
    {           
        // Size  prim // >>>>>>>>>>>>A PARAMETRER  
        X =  0.010;      
        Y =  8.347;      
        Z =  6.700;    
        
        llSetScale ( < X,Y,Z > );
        
        
        
        llSetPrimitiveParams([PRIM_TEXTURE, ALL_SIDES, "e5f7ea6d-ce87-edc9-ea39-7d658c73ff1c",
                          <.5,1.0,0.0>, <0.75,0.0,0.0>,PI_BY_TWO]);  // volet ouvert
        
        Shutter = "OPENED"; // status volet....  
        
        
        Channel_Syn_Channel = -1000;   //  canal de reception du channel  de com qui va être utilisé
        Reset_Syn_Channel   = -1010;   //  canal sortant pour indiqué au HUD  que l'on désire connaitre le cannal à utilisé 
        
        llListen(Channel_Syn_Channel, "", "", ""); // on est pret à recevoir le cannal de comm à utilisé 
        
        llSay (Reset_Syn_Channel, "ASK_SYNC");   // on demande le canal....      
        Motor ("DOWN");   

    }
    
    
    listen( integer channel, string name, key id, string message )
    {
        if (channel == Channel_Syn_Channel)  
        {
            llListen((integer) message, "", "", ""); // Le message du HUD contient le ou LES CANAUX à utilisé
            llOwnerSay ("Synchro done with the HUD");// C'est gràce à cela que les volet pourront être  piloté par plusieurs HUD....        
        }
        else 
            Motor( message );  // Action!!

    }

}

Scrip corrigé le 15 Janvier 2009 suite problème mis en évidence par Ans que je remercie...

Madball Shan · 02/01/2009, 18h54

Oui cela fonctionne

mais c'est super lent par contre

, j'ai du mettre 20 comme vitesse, si tu veux tester c'est a Wild Vertigo que j'ai eu ce problème.

Seb_01 · 02/01/2009, 22h19

Effectivement j'ai testé le lag est si important que la synchro n'existe plus

Je t'explique le principe peut être peux tu ajuster les timings..

Code PHP:


     llSetTextureAnim(ANIM_ON  | SMOOTH | LOOP | REVERSE, ALL_SIDES , 2, 2, 1, 1,1/Timing);        
        llSleep(Timing);
        llSetTextureAnim(FALSE, ALL_SIDES, 0, 0, 0.0, 0.0, 1.0);  // stop l'animation

le paramètre 1/Timing indique le nombre de frames à la seconde.

Prenons un exemple:

Pour un timing de 4s la vitesse sera 1/4 frame par seconde
comme nous avons 1 seule frame le temps sera donc égal = 4 secondes.
(4 * 1/4 pour afficher l'image totale)

donc on lance l'animation et on la stoppe après 4 secondes.

En cas de lag le temps du llSleep dérive il doit être de 4.5 s ou plus... du coup l'animation n'est pas stoppée au bout des 4 secondes...

J'ai une petite idée je vais tester ... @+

Mon idée n'a pas donner de résultat

Il y a trop de scripts en attente ou quelques uns pompent toute les ressources CPU de la région...

relevé de perfs sur la région...

Ans · 15/01/2009, 17h36

Bravo pour ton script

Mais mais bin oui c'est pas parfait

Pour l'usage auquel tu l'as destiné oui à 99.9%

Mais si tu mets une texture avec rayures cela ne va pas , en effet il y a un changement de dimension entre l'enroulement et la position fermée!

Tu change la texture sur toutes les face mais bon c'est a modifier avec "face" et le N° de face c'est bien ça?

Dernier point le volet ouvert devrait être en fantôme cela serait encore mieux

Si tu souhaite voir le script avec la rayure je suis Online sous Ans Seetan

@+

arkoiuga Héros	me revoili me revoila seb avec mon volet j ai bien reussi a faire la texture tout est ok mais encore un tit soucis avec la photo tu comprendra tout. le prims que je fais pour la fenetre est a la taille de la fenetre et ensuite il est devient plus grand comme tu vois sur la photo mais que dans le sens de la hauteur. Images attachées
31/12/2008, 17h33	Télécharger la pièce jointe

arkoiuga Héros	j aimerai savoir s il est possible de faire des volets roulants qui s ouvrent et se ferment de bas en haut et de haut en bas avec une un interrupteur pour commander tous les volets de la maison en meme temps (2 volets)
19/12/2008, 16h43

Seb_01 Alpha & Oméga	Techniquement c'est possible et (pas trop compliqué) as tu fais des recherches sur Xstreet? Si tu ne trouves rien de rien ... on essayera de te créer un truc sympa
19/12/2008, 19h27

Iceman Arkin Alpha & Oméga	Je dois avoir ton bonheur dans mon inventaire ...
20/12/2008, 14h19

arkoiuga Héros	merci pour ta reponse seb j ai reussi a faire le boitier je fais comment pour faire le volet maintenant?
23/12/2008, 18h22

Seb_01 Alpha & Oméga	Demain à ton réveil ce sera publié ici...
23/12/2008, 20h49

arkoiuga Héros	merci seb j ai tout réussis tout fonctionne. Juste une petite chose j essais de mettre ma texture sur le volet je n y arrive pas il repasse an noir a chaque fois
24/12/2008, 11h22

arkoiuga Héros	encore merci seb pour tes reponses rapides j ai un souci je c est pas ce que c est : copy to UUID et remplace mon UUID par la tienne et comment fait t on une texture a moitié transparente ?
24/12/2008, 11h50

Seb_01 Alpha & Oméga	Bravo! 1.stop ton script ( running off ) position basse (fermé donc) 2. ensuite regle le correctement en hauteur z (reajuste la position si besoin) 3. note la valeur Z donnée dans édit 4. reporte cette valeur dans le script 5. compile le + running on 6. cela devrait le faire // Size prim // >>>>>>>>>>>>A PARAMETRER X = 8.700; Y = 0.010; Z = 7.068; <====== Hauteur ton volet
31/12/2008, 17h41

Madball Shan Héroïne	Merci seb pour ce joli tuto J'ai fait des volets moi aussi tout fonctionne bien sauf un petit détail, en fait j ai fait de plus petits volets que les tiens et mon souci viens de la taille de la texture car quand mes volets déroules ça tourne un peu trop, presque en boucle (niveau anim texture), peut-on régler la hauteur de cette texture et si oui, quelle ligne du script. Merci
01/01/2009, 18h38

Madball Shan Héroïne	J'ai refait et tout fonctionne bien maintenant. Merci
01/01/2009, 20h15

arkoiuga Héros	merci seb tout est ok pour moi maintenant
01/01/2009, 21h22

Seb_01 Alpha & Oméga	tu me rassures car je ne voyais pas le problème Je vais mettre ce produit sous Xstreet cela sera plus simple pour les intéressés.. Fait http://uncensored.xstreetsl.com/modu...ItemID=1107520
01/01/2009, 21h31

Madball Shan Héroïne	En fait je pense que c'est un bug du au lag car sur une sim ca fonctionne très bien puis sur une autre ça me fait toujours le même bug
01/01/2009, 23h07

Madball Shan Héroïne	Oui cela fonctionne mais c'est super lent par contre, j'ai du mettre 20 comme vitesse, si tu veux tester c'est a Wild Vertigo que j'ai eu ce problème.
02/01/2009, 18h54

[résolu] volet roulant

Connectés sur ce fil