SL - Forum scripts

[Wiki] Les Particle (Particule)

Répondre
Partager Rechercher
Ce message est en mode wiki. Tous les comptes de plus de 30 jours avec plus de 30 messages peuvent le modifier.

Je me permet de remettre ici un script "basic" de particules, l'original du Wiki ayant été effacé.
Je précise aussi que c'est le modèle de base que j'ai utilisé moi-même pour mes "expérimentations", et qui a été conçu par Mathew Cazalet pour les besoins de l'école (très vieux script du coup ;p!).

Code:
// Les particules par Mathew Cazalet - Ecole de SL - 2007
//Script générique.

//Les paramètres "SRC" affectent la source (le prim), les paramètres "PART" affectent les particules générées

default
{
    state_entry()
    {
        list parametres = [
        //Couleur de départ    
        PSYS_PART_START_COLOR,<0.596,0.984,0.596>,
        //Couleur de fin
        PSYS_PART_END_COLOR,<0.196,0.800,0.196>,
        
        //Taille de départ
        PSYS_PART_START_SCALE, <0.10,0.10,0.10>,
        //Taille de fin (max=<4,4,0>)
        PSYS_PART_END_SCALE, <0.20,0.20,0.20>,
        
        //Transparence de départ
        PSYS_PART_START_ALPHA, 0.8,
        //Transparence de fin
        PSYS_PART_END_ALPHA, 0.6,

        //Nombre de particules par émission
        PSYS_SRC_BURST_PART_COUNT, 4,
        //Temps entre chaque émission
        PSYS_SRC_BURST_RATE, 0.2,

        //Durée de vie des particules (max 30.0 secondes)
        PSYS_PART_MAX_AGE, 1.0,
        //Durée de vie de la source d'émission
        PSYS_SRC_MAX_AGE, 0.0,

        //Comportement de la source d'émission
        PSYS_SRC_PATTERN, 10, //DROP=1, EXPLODE=2, ANGLE=4, ANGLE_CONE=8, ANGLE_CONE_EMPTY=10
        // DROP -> Emmet des particules sans vitesse initiale
        // EXPLODE -> Expulse des particules dans toutes les directions en utilisant les paramètres "BURST".
        // ANGLE -> Envoie les particules sur le plan 2D défini par les angles : "PSYS_SRC_ANGLE_BEGIN" & "PSYS_SRC_ANGLE_END"
        // ANGLE_CONE -> Envoie les particules sur le plan 3D défini par les angles : "PSYS_SRC_ANGLE_BEGIN" & "PSYS_SRC_ANGLE_END"
        // ANGLE_CONE_EMPTY -> Envoie les particules sur le plan 3D qui n'est pas défini par les angles : "PSYS_SRC_ANGLE_BEGIN" & "PSYS_SRC_ANGLE_END"
        
        //----------Uniquement avec type ANGLE

        //Début de l'angle de création de particules
        PSYS_SRC_ANGLE_BEGIN, 0*DEG_TO_RAD,
        //Fin de l'angle de création de particules
        PSYS_SRC_ANGLE_END, 0*DEG_TO_RAD,
        
        //Angle de rotation entre deux émissions
        PSYS_SRC_OMEGA, <4,4,4>*DEG_TO_RAD,
        //---------------------------------------
        
        //Rayon d'émission de particules autour de la source
        PSYS_SRC_BURST_RADIUS, 0.1,
        
        //Vitesse minimale des particules qui partent de la source
        PSYS_SRC_BURST_SPEED_MIN, 0.01,
        //Vitesse maximale des particules qui partent de la source
        PSYS_SRC_BURST_SPEED_MAX, 0.10,
        
        //Mouvement global donné aux particules générées
        PSYS_SRC_ACCEL, <0.0,0.0,0.2>,
        
        
        
        //Les particules suivront la cible (le flag PSYS_PART_TARGET_POS_MASK doit tre actif)
        PSYS_SRC_TARGET_KEY, llGetOwner(),
        
        //Les flags permettent de modifier le comportement global des particules faces à leur environnement
        PSYS_PART_FLAGS,
                
        //PSYS_PART_BOUNCE_MASK|//Les particules rebondissent sur le sol
        PSYS_PART_EMISSIVE_MASK|//Les particules ne sont pas affectées par la lumiere exterieure.
        //PSYS_PART_FOLLOW_SRC_MASK|//Les particules suivent le mouvement de la source
        //PSYS_PART_FOLLOW_VELOCITY_MASK|//Les particules s'orientent en direction de la source
        PSYS_PART_INTERP_COLOR_MASK|//Interpolation de la couleur du début vers la fin
        PSYS_PART_INTERP_SCALE_MASK//Interpolation de la taille du debut vers la fin
        //PSYS_PART_TARGET_LINEAR_MASK|//Les particules vont vers la cible en ligne droite (cf ligne 69)
        //PSYS_PART_TARGET_POS_MASK|//Les particules vont vers la cible en changeant de trajectoire (cf ligne 69)
        //PSYS_PART_WIND_MASK//Les particules sont soumises aux vents
        ];
    
        llParticleSystem(parametres);
    }
}
Dernières modifications :
(Voir) 08/9/2015 11:31:31 : ~#Nyc#~ (Mise en place d'un nouveau script de Particules de Base)
(Voir) (Comparer)10/2/2012 11:53:23 : cupcakes (Je détruit ce que j'ai crèe)
(Voir) (Comparer)22/10/2010 10:06:12 : I am a lollipop (couleur)
Merci Nyc, oui ca serais bien que quelque personne m'aide a complétez ce Wiki :]
Ajout (Poofers).
Ajout =) et modification quelqu'un peut mettre le wiki la haut avec les autres?
J'aimerais juste rajouté un détail vraiment bête mais qui m'a fait me posé beaucoup de questions:

N'oubliez pas de passer votre niveau graphique de faible à moyen ou +. Je vais passer pour le simplet du village mais, jusqu'à aujourd'hui, je ne comprenais pas pourquoi la multitude de scripts que j'essayais, les générateurs automatiques, etc. ne marchaient pas.
Répondre

Connectés sur ce fil

 
1 connecté (0 membre et 1 invité) Afficher la liste détaillée des connectés