[AurelieJolieParis]

bonjour

Je souhaiterai que le owner du prims soit le seule à pouvoir changer la texture on touch.

Code PHP:

default
{
  
     touch_start(integer total_number)
    {
        integer number = llGetInventoryNumber(INVENTORY_TEXTURE);
        float rand = llFrand(number);
        integer choice = (integer)rand;
        string name = llGetInventoryName(INVENTORY_TEXTURE, choice);
        if (name != "")
            llSetTexture(name, ALL_SIDES);
    }
} 

C'est possible ?

merci d'avance

[Kaza]

Oui oui possible :

Code PHP:

default
{
 touch_start(integer total_number) 
 {
 if(llDetectedkey(0) == llGetOwner()) 
  {
  integer number = llGetInventoryNumber(INVENTORY_TEXTURE); 
  float rand = llFrand(number); 
  integer choice = (integer)rand; 
  string name = llGetInventoryName(INVENTORY_TEXTURE, choice); 
  if (name != "")llSetTexture(name, ALL_SIDES); 
  } 
 } 
} 

Que j'aurais plutot écris :

Code PHP:

default
{
touch_start(integer total_number) 
 { 
 if( llDetectedKey(0) == llGetOwner) 
  { 
  string sText = llGetInventoryName(INVENTORY_TEXTURE,llFrand(llGetInventoryNumber(INVENTORY_TEXTURE))); 
  if(sText != "")llSetTexture(sText, ALL_SIDES); 
  } 
 }
} 

Et encore ... la vérification de présence d'une texture est elle nécessaire ?

[-.-]

Joli les tags de couleurs ...
Pour la lisibilité, faudrait peut-être faire du ménage.

[AurelieJolieParis]

ça me dit qu'il y a une erreur de syntaxe.

[Kaza]

Oui bon desolé ... j'ai eu un petit probléme à l'édition ( pas bien de se moquer ming ! )

Je relis ça mais normalement pas de raison ( corrigé une petite erreur )

[Ahuri Serenity]

Citation :

Publié par Kaza

Et encore ... la vérification de présence d'une texture est elle nécessaire ?

Pas ici, car une texture dans l'objet porte forcément un nom.
Attention par contre si il n'y a pas de texture ....

[AurelieJolieParis]

ereur syntax sur le premier

et sur le second

error: name not definied withing scope

[Ahuri Serenity]

Code PHP:

default
{
    touch_start(integer total_number)
    {
        integer iNb = llGetInventoryNumber(INVENTORY_TEXTURE);
 
        if( iNb == 0 || llDetectedKey(0) != llGetOwner() )
            return;
 
        integer iIndex = (integer)llFrand(iNb);
        llSetTexture( llGetInventoryName( INVENTORY_TEXTURE, iIndex), ALL_SIDES);   
    }
} 

[bestmomo]

Il y a un petit truc qui me dérange dans ton script Ahuri, tu ne testes pas si la même texture est sélectionnée une deuxième fois du coup on peut avoir un clic sans changement de texture...

Code PHP:

integer iIndex;
default
{
    touch_start(integer total_number)
    {
        integer iNb = llGetInventoryNumber(INVENTORY_TEXTURE);

        if( iNb == 0 || llDetectedKey(0) != llGetOwner() )
            return;

        if(iNb != 1)
        {
            integer iRand = (integer)llFrand(iNb);
            while(iIndex == iRand) iRand = (integer)llFrand(iNb);
            iIndex = iRand;
        }

        llSetTexture( llGetInventoryName( INVENTORY_TEXTURE, iIndex), ALL_SIDES);
    }
} 

[Ahuri Serenity]

Citation :

Publié par bestmomo

Il y a un petit truc qui me dérange dans ton script Ahuri, tu ne testes pas si la même texture est sélectionnée une deuxième fois du coup on peut avoir un clic sans changement de texture...

Effectivement, mais je me contentais juste de répondre à la question du topic :

Citation :

Je souhaiterai que le owner du prims soit le seule à pouvoir changer la texture on touch.

Je suis d'accord cette modif' est préférable pour être certain du changement.

[AurelieJolieParis]

Grand merci à tous.