[aliagorn]

bonjour a tous, voila, j'aimerais savoir si c'été possible d'avoir un script qui faisais automatiquement défilé les texture mise dans une prime
sans que l'on ne doivent rien rien, exemple ca changerais de texture toute les 5 seconde

Bien sûr il suffit de taper script library dans search et de fouiner , c'est free et full perm . Mon inventaire est trop bordélique pour que j'y retrouve quoi que ce soit mais j'avais pris là bas . C'est plein de scripts pas mal pour tester .

[XanorK]

Bonjour,

Voici un petit script qui devrait faire l'affaire :

Code PHP:

float fTIMER = 5.0; // en secondes
integer iMax;
integer iIndex;

SetTexture(integer i)    {
    string nom = llGetInventoryName(INVENTORY_TEXTURE, i);
    llSetTexture(nom, ALL_SIDES); //enventuellement remplacer ALL_SIDES par le numero de la face
    // voir dans le touch_start ci dessous
}
init()    {
    iMax = llGetInventoryNumber(INVENTORY_TEXTURE);
    iIndex = 0;
    if(iMax)    SetTexture(0);
    if(iMax > 1)    llSetTimerEvent(fTIMER);    
}
default
{
    timer()
    {
        ++iIndex;
        if(iIndex >= iMax)    iIndex = 0;
        SetTexture(iIndex);
    }
    state_entry()
    {
        init();
    }
    changed(integer c)
    {
        if (c & CHANGED_INVENTORY) init();
    }
    ////////////// ce bloc pour determiner le numére de face a mettre dans
    ////////////// la commande llSetTexture.
    touch_start(integer total_number)
    {
        llSay( 0, "la face touché porte le N°" + (string)llDetectedTouchFace(0) );
    }
    /////// effacer ce bloc apres usage ou si ALL_SIDES convient
} 

XanorK