[Val69]

Alors voila j'ai trouvé un script qui permet de donner un objet (ou n'importe quoi) lorsqu'on clique dessus. Sauf que ca marche que pour le propriétaire de l'objet. J'aurais voulu que tout le monde puisse cliquer !

Citation :

default
{
on_rez(integer start_parm)
{
llResetScript();
}
state_entry()
{
llOwnerSay( "Click me to get my Contents!");
string folderName = llGetObjectName();
llSetText(folderName,<0,1,0>,1.0);
}
touch_start(integer total_number)
{
list contents_list;
string contents_name;
integer contents_num = llGetInventoryNumber(INVENTORY_ALL);
string folderName = llGetObjectName();
integer i;
for (i = 0; i < contents_num; ++i)
{
contents_name = llGetInventoryName(INVENTORY_ALL, i);
contents_list += contents_name;
}
i = llListFindList(contents_list, [llGetScriptName()]); // Delete this script
contents_list = llDeleteSubList(contents_list, i, i);


llGiveInventoryList(llGetOwner(), folderName, contents_list);
llInstantMessage(llGetOwner(), "Look in your inventory for a folder called: "
+ folderName + ". This folder contains your Stuff."); // Alert the user.
}
}
}

J'ai déjà enlevé une ligne qui disait que vous n'étiez pas le propriétaire de l'objet mais je crois que ca ne marche toujours pas, ca doit prendre comme "destinataire" le propriétaire de l'objet.

en faite je pense que c'est cette ligne qui foire :
llGiveInventoryList(llGetOwner(), folderName, contents_list);

faudrait plutôt mettre (je pense) quelque chose comme ça :
llGiveInventoryList(llGetCeluiQuiACliqué(), folderName, contents_list);

ainsi que pour ça :
llInstantMessage(llGetOwner(),
Maerci de m'aider !!!!

[master71]

voilà:

Code:

default {
    on_rez(integer start_parm) {
        llResetScript(); }
    
    state_entry() {
        llSetText("click me to get my content", <0.0, 1.0, 0.0>, 1.0); }
    
    touch_start(integer total_number) {
        list cList;
        string nContent = "";
        string nFolder = llGetObjectName();
        string nScript = llGetScriptName();
        integer iContents = llGetInventoryNumber(INVENTORY_ALL);
        integer i;
        key cliqueur = llDetectedKey(0);
        for (i = 0; i < iContents; i++) {
            nContent = llGetInventoryName(INVENTORY_ALL, i);
            cList += nContent; }
        i = llListFindList(cList, [nScript]);
        cList = llDeleteSubList(cList, i, i);
        llGiveInventoryList(cliqueur, nFolder, cList);
        llInstantMessage(cliqueur, "Look in your inventory for a folder called: " + nFolder + ". This folder contains your Stuff.");
        llResetScript(); } }

PS: au lieu de Citation, utilise Code

[Val69]

Ca a l'air de marcher... Maerci beaucouuuuuuuuuuuuuuuuuuuuuuuuuuuup !
PS : désolé j'avais pas vu le bouton code