[Script] Ronds de fumée

supernova · 13/03/2007, 11h12

Bonjour à tous

voilà un petit moment que je cherche le script permettant de faire des ronds de fumée avec une cigarette, est-ce que quelqu'un l'aurait sous la manche?

merci d'avance

Seb Neox · 13/03/2007, 11h55

Ca doit pas etre simpla a faire en particule, sauf en utilisant une texture. Je vais voir mais n'attends rien de moi dans l'immédiat, y'a d'autres priorités ;-)

bon courage quand meme

supernova · 13/03/2007, 12h26

Salut Seb, merci pour ta réponse

a vrai dire, le script existe, mais je doute qu'il soit disponible, ou peut être dans certains milieux underground

master71 · 13/03/2007, 12h36

y a pas mal de cigares et cigarettes freebies qui font de la fumée.

quand au rond de fumée... hum c'est juste un paramétrage précis d'un générateur de particules.

supernova · 13/03/2007, 13h11

Bonjour Master71, merci de faire avancer le schmilblick

c'est donc un effet de particules... voilà qui est intéressant, de quoi m'orienter vers quelque chose de plus précis

Sinon, vous voyez précisément de quel effet je parle?

master71 · 13/03/2007, 13h23

si tu parles du vrai rond de fumée, oui je vois très bien, je vais regarder ça sur les particules, mais ça va être un burst en cône sur un angle assez ouvert, avec des particules semi-transparentes, et une vitesse relativement faible.

Ha et faut que ça suive le vent

master71 · 13/03/2007, 14h38

bon, un script, et surtout le paramétrage de llParticleSystem():

Code:

// Particle Script 0.5
// Created by Ama Omega
// 3-26-2004
// tweaked by Eep Quirk, 3/18/05,6/19/06

integer on;

particles()
{
// mask flags - set to TRUE (or 1) to enable
integer bounce = 0;    // Make particles bounce on Z plane of object
integer glow = 0;        // Make the particles glow
integer interpColor = 1;    // Go from start to end color
integer interpSize = 1;    // Go from start to end size
integer followSource = 1;    // Particles follow the source
integer followVel = 0;    // Particles turn to velocity direction
integer wind = 1;        // Particles affected by wind

//pattern:
//integer pattern = PSYS_SRC_PATTERN_ANGLE;
//integer pattern = PSYS_SRC_PATTERN_ANGLE_CONE_EMPTY;
integer pattern = PSYS_SRC_PATTERN_ANGLE_CONE;
//integer pattern = PSYS_SRC_PATTERN_DROP;
//integer pattern = PSYS_SRC_PATTERN_EXPLODE;

// Select a target for particles to go towards
// "" for no target, "owner" will follow object owner 
//    and "self" will target this object
//    or put the key of an object for particles to go to
key target = "";
//key target = "self";
//key target = "owner";

// particle parameters
float age = 10;                  // Life of each particle

float maxSpeed = 0.1;            // Max speed each particle is spit out at
float minSpeed = 0.1;            // Min speed each particle is spit out at

string texture = "";           // Texture used for particles, default used if blank
float startAlpha = 0.5;           // Start alpha (transparency) value
float endAlpha = 0.8;           // End alpha (transparency) value (if interpColor = TRUE)

vector startColor = <0.3,0.3,0.3>;    // Start color of particles <R,G,B>
vector endColor = <0.5,0.5,0.5>;      // End color of particles <R,G,B> (if interpColor = TRUE)

vector startSize = <0.05,0.05,0>;     // Start size of particles <x,y>
vector endSize = <0.2,0.2,0>;       // End size of particles (if interpSize == TRUE)

vector push = <0,0,0>;          // Force pushed on particles

// system parameters
float life = 0;             // Life in seconds for the system to make particles
integer count = 1500;        // How many particles to emit per BURST 
float rate = 5;            // How fast (rate) to emit particles
float radius = 0.1;          // Radius to emit particles for BURST pattern
float outerAngle = PI /4;    // Outer angle for all ANGLE patterns
float innerAngle = PI / 4 - 0.1;    // Inner angle for all ANGLE patterns
vector omega = <0,0,0>;    // Rotation of ANGLE patterns around the source

integer flags = 0;
    if (target == "owner") target = llGetOwner();
    if (target == "self") target = llGetKey();
    if (glow) flags = flags | PSYS_PART_EMISSIVE_MASK;
    if (bounce) flags = flags | PSYS_PART_BOUNCE_MASK;
    if (interpColor) flags = flags | PSYS_PART_INTERP_COLOR_MASK;
    if (interpSize) flags = flags | PSYS_PART_INTERP_SCALE_MASK;
    if (wind) flags = flags | PSYS_PART_WIND_MASK;
    if (followSource) flags = flags | PSYS_PART_FOLLOW_SRC_MASK;
    if (followVel) flags = flags | PSYS_PART_FOLLOW_VELOCITY_MASK;
    if (target != "") flags = flags | PSYS_PART_TARGET_POS_MASK;
    llParticleSystem([  PSYS_PART_MAX_AGE,age,
                        PSYS_PART_FLAGS,flags,
                        PSYS_PART_START_COLOR, startColor,
                        PSYS_PART_END_COLOR, endColor,
                        PSYS_PART_START_SCALE,startSize,
                        PSYS_PART_END_SCALE,endSize, 
                        PSYS_SRC_PATTERN, pattern,
                        PSYS_SRC_BURST_RATE,rate,
                        PSYS_SRC_ACCEL, push,
                        PSYS_SRC_BURST_PART_COUNT,count,
                        PSYS_SRC_BURST_RADIUS,radius,
                        PSYS_SRC_BURST_SPEED_MIN,minSpeed,
                        PSYS_SRC_BURST_SPEED_MAX,maxSpeed,
                        PSYS_SRC_TARGET_KEY,target,
                        PSYS_SRC_ANGLE_BEGIN,innerAngle, 
                        PSYS_SRC_ANGLE_END,outerAngle,
                        PSYS_SRC_OMEGA, omega,
                        PSYS_SRC_MAX_AGE, life,
                        PSYS_SRC_TEXTURE, texture,
                        PSYS_PART_START_ALPHA, startAlpha,
                        PSYS_PART_END_ALPHA, endAlpha
                            ]);}

default {
    state_entry() {
        on = 1;
        particles(); }
    
    touch_start(integer touches){
        if (on == 1) {
            on = 0;
            llParticleSystem([]); }
        else {
            on = 1;
            particles(); } } }

supernova · 13/03/2007, 17h58

Master71, je crois que tu mérites ton pseudo

merci beaucoup !

master71 · 13/03/2007, 18h20

de rien.

Denier Ritt · 15/03/2007, 15h23

Merci beaucoup c'est exactement ce que je cherchais.

Mais il me reste une petite question
Ce script on le place dans une cigarette ??
si oui on peut le mettre dans une cigarette freebies ?

master71 · 15/03/2007, 16h56

tu le mets où tu veux, pour ma part il est dans une cheminée décorative, mais bon, là c'est un script qui lance les ronds au 'touch', faut adapter si tu veux le mettre dans une cigarette (même freebie à condition que tu puisses la modifier.)

Denier Ritt · 16/03/2007, 21h06

Merci beaucoup je vais essayer ça ce soir

supernova · 04/05/2007, 10h31

Bonjour à tous

comme certains l'ont probablement remarqués, depuis l'avant dernière mise à jour, le script ne fonctionne plus. Une idée peut etre sur le pourquoi de ce dysfonctionnement?

merci d'avance

master71 · 04/05/2007, 21h44

bon, j'aurais bien été voir ça, mais SL a dit que je devrais sortir au ciné...

[Edit:] J'ai réussi à me logguer, bon.
bah copier le script, coller le script dans un prim, toucher le prim, ça marche... j'ai de beaux ronds de fumée comme avant.

supernova Héros	Bonjour à tous voilà un petit moment que je cherche le script permettant de faire des ronds de fumée avec une cigarette, est-ce que quelqu'un l'aurait sous la manche? merci d'avance
13/03/2007, 11h12

Seb Neox Alpha & Oméga	Ca doit pas etre simpla a faire en particule, sauf en utilisant une texture. Je vais voir mais n'attends rien de moi dans l'immédiat, y'a d'autres priorités ;-) bon courage quand meme
13/03/2007, 11h55

supernova Héros	Salut Seb, merci pour ta réponse a vrai dire, le script existe, mais je doute qu'il soit disponible, ou peut être dans certains milieux underground
13/03/2007, 12h26

master71 Alpha & Oméga	y a pas mal de cigares et cigarettes freebies qui font de la fumée. quand au rond de fumée... hum c'est juste un paramétrage précis d'un générateur de particules.
13/03/2007, 12h36

supernova Héros	Bonjour Master71, merci de faire avancer le schmilblick c'est donc un effet de particules... voilà qui est intéressant, de quoi m'orienter vers quelque chose de plus précis Sinon, vous voyez précisément de quel effet je parle?
13/03/2007, 13h11

master71 Alpha & Oméga	si tu parles du vrai rond de fumée, oui je vois très bien, je vais regarder ça sur les particules, mais ça va être un burst en cône sur un angle assez ouvert, avec des particules semi-transparentes, et une vitesse relativement faible. Ha et faut que ça suive le vent
13/03/2007, 13h23

supernova Héros	Master71, je crois que tu mérites ton pseudo merci beaucoup !
13/03/2007, 17h58

Denier Ritt Héros	Merci beaucoup c'est exactement ce que je cherchais. Mais il me reste une petite question Ce script on le place dans une cigarette ?? si oui on peut le mettre dans une cigarette freebies ?
15/03/2007, 15h23

master71 Alpha & Oméga	tu le mets où tu veux, pour ma part il est dans une cheminée décorative, mais bon, là c'est un script qui lance les ronds au 'touch', faut adapter si tu veux le mettre dans une cigarette (même freebie à condition que tu puisses la modifier.)
15/03/2007, 16h56

Denier Ritt Héros	Merci beaucoup je vais essayer ça ce soir
16/03/2007, 21h06

supernova Héros	Bonjour à tous comme certains l'ont probablement remarqués, depuis l'avant dernière mise à jour, le script ne fonctionne plus. Une idée peut etre sur le pourquoi de ce dysfonctionnement? merci d'avance
04/05/2007, 10h31

master71 Alpha & Oméga	bon, j'aurais bien été voir ça, mais SL a dit que je devrais sortir au ciné... [Edit:] J'ai réussi à me logguer, bon. bah copier le script, coller le script dans un prim, toucher le prim, ça marche... j'ai de beaux ronds de fumée comme avant.
04/05/2007, 21h44

[Script] Ronds de fumée

Connectés sur ce fil