[gxkill]

Bonjour à toutes et tous

Je me permet de poster une petite demande , je suis a la recherche d'un script qui quand je le met dans une prim en forme de grosse balle le gonfle .

La chose qui me serais le plus simple pour mon utilisation :

que je puisse à l'aide d'un bouton simple porter comme un hud quand je clic , la boule rezz de tout petit a assez grand de quoi m'envelopper ... et un autre clic sur le bouton pour tuer le prim ... ou un autre bouton je ne sais pas ce qui est mieux ou plus simple

je vous joint un exemple en gif que j'ai trouver qui fait exactement ce que j'aimerais ... le probléme c'est que ce n'est pas moi sur l'image et que je ne sais pas ou trouver cela

https://gyazo.com/fe9943717b7c9bf49d72cd13f0dcab80

un grand merci pour votre aide

[MenthalOH]

Voilà un essai simple.....
mettre un bouton en hud, mettre dans ce hud une petite sphère creuse ( 5cm par ex), translucide, rose, réglée en "fantome" et contenant ce script....

Code PHP:

key owner;

integer canal;
integer count;

default
{
    on_rez(integer start_param)
    {
        llResetScript();
    }
    
    state_entry()
    {
        owner = llGetOwner();
        canal = (integer)("0xA" + llGetSubString((string)owner, 0,6 ));
        llListen(canal, "", NULL_KEY, "Die");
        llSetTimerEvent(1.0);
    }

    listen(integer channel, string name, key id, string message)
    {
        llDie();
    }
    
    timer()
    {
        llSetTimerEvent(0.2);
        llScaleByFactor(1.15);
        count++;
        if(count == 20)
        {
            llSetTimerEvent(0.0);
        }
    }
} 

puis mettre ce script dans le bouton hud lui même qui va rez la bulle...

Code PHP:

key owner;

integer canal;

default
{
    on_rez(integer start_param)
    {
        llResetScript();
    }
    
    state_entry()
    {
        owner = llGetOwner();
        canal = (integer)("0xA" + llGetSubString((string)owner, 0,6 ));
    }
        
    touch_start(integer total_number)
    {
        llRezObject(llGetInventoryName(INVENTORY_OBJECT, 0),llGetPos()+<0.3,0.0,0.6>, ZERO_VECTOR, llGetRot(),canal);
    }

 changed(integer change)
    {
        if (change & CHANGED_OWNER) 
        {
            llResetScript();
        }
    }
} 

et enfin un deuxieme petit bouton, pour le kill de la bulle contenant ça.....

Code PHP:

key owner;

integer canal;

default
{
    on_rez(integer start_param)
    {
        llResetScript();
    }
    
    state_entry()
    {
        owner = llGetOwner();
        canal = (integer)("0xA" + llGetSubString((string)owner, 0,6 ));
    }
        
    touch_start(integer total_number)
    {
        llRegionSay( canal, "Die");
    }
    
    changed(integer change)
    {
        if (change & CHANGED_OWNER) 
        {
            llResetScript();
        }
    }
} 

[gxkill]

super Menthal c'est tout a fait cela que j'avais besoin // grand merci

dernière question bonus , si je veux que la boule de départ sois encore plus petite au début du rezz ( en gros que d'avoir cette impresson comme sur le gif ), quelle ligne dois je modifier ? car j'ai l'impression que le script définit la taille de la boule avant que je la gonfle ..

merci beaucoup

[MenthalOH]

non, il faut la mettre ds le rezzeur à la taille de départ souhaitée. Mais, il faudra aussi modif le nombre d' aggrandissement alors, avec "count"....

[gxkill]

merci merci Menthal