[EvilBisounoursX]

Bonjour,

dans mon magasin il y a un vêtement que j'aimerais réserver qu'à mon groupe, j'ai vu dans la bibliothèque qu'il y avait un scripte pour limiter à un nombre de personne un objet, mais pas de groupe, (dans mon groupe on est plus de 1500 donc je ne peux pas faire du nom par nom lol).

Voilou, donc si ça existe, j'suis preneur, et merci d'avance pour vos réponses.

[Pluton3]

Je suis sur que tu na pas cherché dans la recherche Google ou encore ici sur JeuxOnline dans les sujets, le script que tu cherche est dans un sujets ici si tu cherche bien tu le trouvera =D on n'est jamais mieux servi que par soit mème.

[EvilBisounoursX]

j'avoue j'étais entre deux quand j'ai posté, la je suis plus posé j'vais pouvoir chercher, cela dit si vous avez la réponse ^^

[Elenia Boucher]

Aller je te met sur la piste; à compléter

Code:

money(key id, integer  amount){
    if(llSameGroup(id)) llGiveInventory... 
    else llGiveMoney(id, amount);//sinon on rend les sous !!
}

Il faut bien sur que le script ait l'autorisation de prendre des sous sur ton compte.llRequestPermissions(llGetOwner(), PERMISSION_DEBIT ) quelque part. Si tu trouve un script vendor correct quelque part avec ça tu devrais pouvoir l'adapter

[EvilBisounoursX]

OK merci, bon, 2e difficulté savoir scripter xD

[XanorK]

Voila qui devrait faire l'affaire :

Code PHP:

integer iPrixVente = 12; // mettre le bon prix ici
string NomDossier =    "NOM DU DOSSIER DANS l'inventaire"; // a changer



key kOwner;
list lVetements;
init()    {
    kOwner = llGetOwner();
    llRequestPermissions(kOwner, PERMISSION_DEBIT);
}
creatList()    {
    integer i;
    integer nbClothes = llGetInventoryNumber(INVENTORY_ALL); //au cas ou y'aurait des attachements
    lVetements = [];
    for(; i<nbClothes; ++i)    {
        string nom = llGetInventoryName(INVENTORY_ALL, i);
        if (llGetInventoryType(nom) != INVENTORY_SCRIPT) // je donne pas les scripts
            lVetements += [nom];
    }

    // si list vide, je mets pas en vente
    if (llGetListLength(lVetements))
        llSetPayPrice(PAY_HIDE, [iPrixVente, PAY_HIDE, PAY_HIDE, PAY_HIDE]);
    else
        llSetPayPrice(PAY_HIDE, [PAY_HIDE, PAY_HIDE, PAY_HIDE, PAY_HIDE]);
        
}
default
{
    money(key giver, integer amount)
    {
        if (amount != iPrixVente) return; // tentative d'arnaque, on sait jamais
        if (llSameGroup(giver))    { //giver meme group que objet
            llSay(0, "Merci de ton achat, livraison ...");
            llGiveInventoryList(giver, NomDossier, lVetements);
            llInstantMessage(kOwner, "Vente de la tenue machin à " + llKey2Name(giver));
        }
        else    {
            llSay(0, "Reservé au group machin truc. je vous rembourse");
            llInstantMessage(kOwner, "Vente avorté de la tenue du groupe à " + llKey2Name(giver));
            llGiveMoney(giver, amount);
        }
    }
    run_time_permissions(integer p)
    {
        if (!(p & PERMISSION_DEBIT))
            llRequestPermissions(kOwner, PERMISSION_DEBIT);
    }
    state_entry()
    {
        init();
        creatList();
    }
    changed(integer c)
    {
        if(c & CHANGED_OWNER)        llResetScript();
        if(c & CHANGED_INVENTORY)    creatList();
    }
} 

XanorK