[Rems57]

Bonjour/Bonsoir,

Je viens poser une petite question , enfaîte je cherche un script qui permet de jouer un son, une fois qu'on a envoyer un text dans le chat local.

Je m'explique: Il ne s'agit pas d'un son joué pendant que j'écris mais une fois que j'ai envoyé le message, je ne sais pas si c'est clair ?

J'ai chercher sur Google, JOL, xstreet ...

En espérant qu'un personne pourrais m'aider...

amicalement

[Aleah]

Bonsoir
Tu peux faire ça simplement avec une gesture. Faut mettre ton texte déclencheur dans la case trigger de la gesture.

Sinon voici un script dans lequel tu peux changer:
- le channel: integer channel = 1; faut éviter le channel public 0
- le texte déclencheur: string msg = "texte";
- le nom du son: string soundname = "son";

Code:

integer listener;
integer channel = 1;
string msg = "texte";
string soundname = "son";

default
{
    state_entry()
    {
        listener = llListen(channel,"","",msg);
    }

    listen(integer channel, string name, key id, string message)
    {
        llPlaySound(soundname,1.0);
    }
}

[Rems57]

Alors, merci pour ta réponse l'âme mais je crois que je me suis mal fait comprendre ...

C'est pas pour un texte en particulier, un message en particulier, sinon je fais une gesture oui, je peu me débrouiller la dessus ^^ ...

Mais ce que je cherche c'est un typing script c'est a dire quand on parle dans le chat local, (il en existe pour les animation (avatar tape sur un clavier pendant qu'il écrit) et moi je cherche un qui joue un son APRES avoir écris , donc :

Mon avatar écrit dans le chat local--> Rien
Le message est envoyé-->jouer un son

PS: dur dur lol

Mais merci de ta réponse !

[black cats]

Le script est à l'écoute de ce que tu dis dans le chat local.

Code:

llListen(0,"",llGetOwner(),"");

A chaque fois qu'il t'entend dire quelque chose, l'événement listen est déclenché,

Code PHP:

listen(integer channel, string name, key id, string str) 

tu peux alors lui faire exécuter une action, en l’occurrence jouer un son.

Code PHP:

string sound;

default
{
   state_entry()
   {
   llListen(0,"",llGetOwner(),"");
   sound = llGetInventoryName(INVENTORY_SOUND,0);
   }

   listen(integer channel, string name, key id, string str)
   {
   llPlaySound(sound, 1.0);
   }

   changed(integer change)
   {
   if (change&CHANGED_INVENTORY) sound = llGetInventoryName(INVENTORY_SOUND,0);
   else if (change&CHANGED_OWNER) llResetScript();
   }
} 

[Rems57]

exactement ce que je recherche mille merci !!!

[lola08]

bonjour à tous !

je recherches un script permettant d'émettre un son lorsque mon avatar ecrit !!

merci d'avance de vos réponses

[bestmomo]

Un truc tout simple comme ça devrait aller :

Code PHP:

// Volume du son (entre 0 et 1)
float f_volume = 1.0;

// Son à jouer qui doit se trouver dans l'inventaire avec le script
string s_son = "mon_son";

integer i_son_on;

default
{
    state_entry() {
        llSetTimerEvent(.5);
    }

    timer() {
        integer info = llGetAgentInfo(llGetOwner());
        if((info & AGENT_TYPING) && !i_son_on) {
            i_son_on = TRUE;
            llLoopSound(s_son, f_volume);
        }
        else if (!(info & AGENT_TYPING) && i_son_on){
            llStopSound();
            i_son_on = FALSE;
        }
    }
} 

[lola08]

un grand merci avec du retard du aux vacances merci de ton aide !