[Ceejay]

Bonjour,

je voudrais faire un hud avec un glow en intensité avec des boutons du genre 10% , 20% , 30% etc qui s'applique sur une prim,
j'ai chercher sur ce forum et sur le web mais je trouve pas, quelqu'un pourrais m'aider svp

[MenthalOH]

hellow...faire un HUD avec par exemple 11 boutons.....dont les descriptions du prim vont de 0.0 à 1.0
nommer ce HUD "HUD_Glow".....et ajouter ce script dans le prim racine du hud....



integer canal;

default
{
on_rez(integer start_param)
{
llResetScript();
}

state_entry()
{
canal = (integer)("0xA"+llGetSubString((string)llGetOwner(),0,6));
}


touch_start(integer total_number)
{
integer prim = llDetectedLinkNumber(0);

if(prim>1)
{
list params = llGetLinkPrimitiveParams(prim, [PRIM_DESC]);
string msg = llList2String(params, 0);

llRegionSay(canal,msg);
}
}


changed(integer mask)
{
if(mask & CHANGED_OWNER)
{
llResetScript();
}
}
}



mettre le script suivant dans le prim à glower......


integer canal;

default
{
on_rez(integer start_param)
{
llResetScript();
}

state_entry()
{
canal = (integer)("0xA"+llGetSubString((string)llGetOwner(),0,6));
llListen(canal, "HUD_Glow", NULL_KEY, "");
}

listen( integer canal, string name, key id, string msg)
{
llSetLinkPrimitiveParamsFast(LINK_THIS,[PRIM_GLOW, ALL_SIDES,(float)msg]);
}

changed(integer mask)
{
if(mask & CHANGED_OWNER)
{
llResetScript();
}
}
}

[Ceejay]

merci beaucoup, la 1ère partie je dois le mettre sur tous les boutons ? ,les renommer ?

[MenthalOH]

pas de script dans les boutons, juste ds le prim racine du HUD, ne pas les renommer, mais changer la description des boutons (ligne en dessous du nom).

[Ceejay]

j'ai bien fait comme tu dis mais sa ne marche pas

[MenthalOH]

as-tu bien mis le nom "HUD_Glow" au HUD ??

[Ceejay]

oui j'ai copier le texte "HUD_Glow" sur ton message pour être sûr je l'ai mis dans la description des boutons et placer le script a la racine du HUD

[MenthalOH]

lol....reprenons.....la description des boutons doit être... 0.0, 0.1, 0.2.......1.0......le nom du HUD doit être HUD_Glow ......sinon IM moi, je te file le modèle....Menthal Oh